Option Explicit
 
Dim sMSUFileNamePath, sMSUFileName, sMSUFilePath
Dim oShell, sTargetFolder
 
Do Until False
  If WScript.Arguments.Count = 0 Then
    Registry_Value_Set "HKCR", _
                     "Microsoft.System.Update.1\shell\expand\command", _
                     "", _
                     "wscript """ & WScript.ScriptFullName & """ ""%1""", _
                     "REG_SZ"
    MsgBox "Der Kontext-Menü-Handler wurde registriert.", vbOKOnly, "SoftService Installer"
    Exit Do
  End if  
 
  sMSUFileNamePath = WScript.Arguments.Item(0)
  sMSUFileName = Mid(sMSUFileNamePath, InStrRev(sMSUFileNamePath, "\") + 1)
  sMSUFilePath = Left(sMSUFileNamePath, instrrev(sMSUFileNamePath, "\") - 1)
 
  sTargetFolder = sMSUFilePath & "\" & Left(sMSUFileName, Len(sMSUFileName) - 4)
  if not Folder_Create(sTargetFolder) Then Exit Do
 
  Set oShell = CreateObject("WScript.Shell")
 
  oShell.run "cmd /c expand -f:* """ & sMSUFileNamePath & """ """ & sTargetFolder & """", 1, True
  Set oShell = Nothing
  Exit Do
loop  
 
' Creates nested folders. Returns "True" if folder already exists or created successfully.
Private Function Folder_Create(i_FolderName)
  Dim oFSO
 
  Set oFSO = CreateObject("Scripting.FileSystemObject")
  Do Until False
    If oFSO.FolderExists(i_FolderName) Then Exit Do
    If Len(i_FolderName) = 0 Then Exit Do
 
    If Not Folder_Create(oFSO.GetParentFolderName(i_FolderName)) Then Exit Do
 
    oFSO.CreateFolder(i_FolderName)
    Exit do
  loop  
  Folder_Create = oFSO.FolderExists(i_FolderName)
  Set oFSO = Nothing   
End Function
 
Public Function Registry_Value_Set(ByVal i_Root, ByVal i_KeyPath, ByVal i_Value, ByVal i_Data, ByVal i_DataType)
  Dim objRegistry, objMethod, objInParam
 
	Do Until False
    Registry_Value_Set = False
 
    If Not NormalizeRegistryRoot(i_Root) Then Exit do  
    If Not NormalizeRegistryDataType(i_DataType) Then Exit do  
 
    Set objRegistry=GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv")
 
	  Set objMethod	= objRegistry.Methods_(i_DataType)
	  Set objInParam = objMethod.inParameters.SpawnInstance_()
 
	  objRegistry.CreateKey i_Root, i_KeyPath
	  with objInParam
	    .hDefKey = i_Root: .sSubKeyName = i_KeyPath: .sValueName = i_Value
	    Select Case i_DataType
	      Case "SetStringValue":         .sValue = i_Data
	      Case "SetExpandedStringValue": .sValue = i_Data
	      Case "SetMultiStringValue":    .sValue = i_Data
	      Case "SetDWORDValue":          .uValue = CLng(i_Data)
	    End Select  
	  End with  
	  call objRegistry.ExecMethod_(i_DataType, objInParam)
 
    Registry_Value_Set = True: Exit Do
  Loop
  Set objRegistry = Nothing
End function    
 
Private Function NormalizeRegistryDataType(ByRef o_DataType)
 
  Do Until False
    NormalizeRegistryDataType = False
 
    Select Case lcase(o_DataType)
      Case "binary",         "reg_binary":           o_DataType = "SetBinaryValue"
      Case "dword",          "reg_dword":            o_DataType = "SetDWORDValue"
      Case "expandedstring", "reg_expanded_sz":      o_DataType = "SetExpandedStringValue"
      Case "multistring",    "reg_multi_sz":         o_DataType = "SetMultiStringValue"
      Case "string",         "reg_sz":               o_DataType = "SetStringValue"
    End Select
 
    NormalizeRegistryDataType = True: Exit Do
  loop  
End function
 
Private Function NormalizeRegistryRoot(ByRef o_Root)
  Const HKEY_CLASSES_ROOT 	= &H80000000
	Const HKEY_CURRENT_USER 	= &H80000001
  const HKEY_LOCAL_MACHINE  = &H80000002
	Const HKEY_USERS 		      = &H80000003
 
  Do Until False
    NormalizeRegistryRoot = false
 
    Select Case o_Root
      Case "HKEY_CLASSES_ROOT",  "HKCR", HKEY_CLASSES_ROOT:       o_Root = HKEY_CLASSES_ROOT
      Case "HKEY_CURRENT_USER",  "HKCU", HKEY_CURRENT_USER:       o_Root = HKEY_CURRENT_USER  
      Case "HKEY_LOCAL_MACHINE", "HKLM", HKEY_LOCAL_MACHINE:      o_Root = HKEY_LOCAL_MACHINE
      Case "HKEY_USERS",         "HKU",  HKEY_USERS:              o_Root = HKEY_USERS  
      Case Else:                                                  Exit do
    End Select
 
    NormalizeRegistryRoot = True: Exit Do
  Loop
End Function